home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1995 #5 & #6 / Amiga Plus CD - 1995 - No. 5 and 6.iso / tex / mf / inputs / test / 6test.mf < prev    next >
Text File  |  1993-11-28  |  2KB  |  57 lines
  1. % This tries all characters on TEST.MF using six different sets of parameters
  2. if unknown cmbase: input cmbase fi % omit if CMMF can be assumed
  3. mag=.5; screen_rows:=400; screen_cols:=600;
  4.  
  5. mode_setup; let mode_setup=\;
  6.  
  7. boolean running;
  8. def abort = hide(scrollmode; running:=false) enddef;
  9. def pause=stop "done with char "&decimal charcode&". " enddef;
  10. let iff=always_iff;
  11. def ligtable text t=enddef;
  12. def charlist text t=enddef;
  13. def extensible text t=enddef;
  14.  
  15. string currenttitle;
  16. let semi=;; let echar=endchar; let endchar=enddef;
  17. def cmchar expr s = currenttitle:=s;
  18.  let;=testchar semi quote def chartext=enddef;
  19. def testchar = semi let;=semi;
  20.  % now `chartext echar' will generate the character to be tested
  21.  running:=true; errorstopmode;
  22.  for k=1 upto 6:
  23.   if running: if known params[k]: scantokens params[k]; font_setup;
  24.     currentwindow:=k;
  25.     currenttitle & ", " & fontname[k];
  26.     chartext echar; fi fi endfor
  27.  pause; enddef;
  28.  
  29. string params[],fontname[];
  30. params[1]="roman_params"; fontname[1]="cmr10";
  31. params[2]="sans_params"; fontname[2]="cmssbx10";
  32. params[3]="tt_params"; fontname[3]="cmtt10";
  33. params[4]="bold_params"; fontname[4]="cmb10";
  34. params[5]="quote_params"; fontname[5]="cmssqi8";
  35. params[6]="ital_params"; fontname[6]="cmti10";
  36.  
  37. w_rows=floor 1/2 screen_rows; w_cols=floor 1/3 screen_cols;
  38. def open(expr k,i,j)=
  39.  openwindow k from ((i-1)*w_rows,(j-1)*w_cols) to (i*w_rows,j*w_cols)
  40.  at (-10,140) enddef;
  41. def openit =
  42.  open(1,1,1); open(2,1,2); open(3,1,3);
  43.  open(4,2,1); open(5,2,2); open(6,2,3); enddef;
  44.  
  45. begingroup delimiters begintext generate;
  46.  def makedef(expr s)(text t) =
  47.   expandafter def scantokens s = t enddef; flushtext enddef;
  48.  def flushtext suffix t = enddef;
  49.  for k=1 upto 6: if known params[k]:
  50.  makedef(params[k])
  51.   expandafter expandafter expandafter begintext
  52.   scantokens ("input "&fontname[k]); fi endfor
  53. endgroup;
  54.  
  55. input test;
  56. bye
  57.